<!--
  A pipeline that converts mathdox documents into XHTML+MathML.
-->
<p:config 
  xmlns:context='java:org.orbeon.oxf.pipeline.StaticExternalContext'
  xmlns:mathdox="http://www.mathdox.org/MathDox"
  xmlns:oxf='http://www.orbeon.com/oxf/processors'
  xmlns:p='http://www.orbeon.com/oxf/pipeline'
  xmlns:property='java:org.mathdox.player.PropertyWrapper'
  xmlns:xhtml='http://www.w3.org/1999/xhtml' 
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:xsl='http://www.w3.org/1999/XSL/Transform'
>
  <!-- 
    The input is a mathdox document.
  -->
  <p:param name='data' type='input'/>
  
  <!--
    The output is an XHTML+MathML document.
  -->
  <p:param name='data' type='output'/>

  <!--
    The context is (possibly) altered by the execution of the mathdox document.
  -->
  <p:param name='instance' type='input'/>
  <p:param name='instance' type='output'/>

  <p:processor name='oxf:identity'>
    <p:input name='data' href='#instance'/>
    <p:output name='data' ref='instance'/>
  </p:processor>

  <p:choose href='#instance'>
    <p:when test='(string(/wrapper/media)="pdf")'
    >
      <p:processor name='oxf:identity'>
        <p:input name='data' href='#data'/>
        <p:output name='data' ref='data'/>
      </p:processor>
    </p:when>
    <p:otherwise>
      <!--
        Convert imageobject/imagedata with type='geogebra' to an applet
      -->
      <p:processor name='oxf:unsafe-xslt'>
        <p:input name='config'>
          <xsl:transform version='2.0'>
            <xsl:import href='oxf:/oxf/xslt/utils/copy.xsl'/>
    
            <!--
              if an image of type geogebra is found change it into an applet
            -->
            <xsl:template match='mediaobject[imageobject[imagedata/@format="geogebra"]] | 
              mediaobject[imageobjectco[imageobject/imagedata/@format="geogebra"]]'
            >
              <!--
                store the imagedata in a variable
              -->
              <xsl:variable name='imagedata' select='imageobject/imagedata[@format="geogebra"]'/>
    
              <xsl:choose>
                <xsl:when test='property:getString("org.mathdox.phrasebook.geogebra.archive.geogebraweb") != ""'>
                  <xhtml:article>
                    <xsl:attribute name='class' select='"geogebraweb"'/>
                    <xsl:apply-templates select='$imagedata/@*' mode='geogebraweb'/>
                    <xsl:apply-templates select='$imagedata/*' mode='geogebraweb'/>
                  </xhtml:article>
                </xsl:when>
                <xsl:otherwise>
                  <xhtml:applet 
                    code='geogebra.GeoGebraApplet'
                  >
                    <xsl:variable name='archive'>
                      <xsl:choose>
                        <xsl:when test='$imagedata/@version="3"'>
                          <xsl:value-of select='property:getString("org.mathdox.phrasebook.geogebra.archive.version3")'/>
                        </xsl:when>
                        <xsl:when test='$imagedata/@version="4"'>
                          <xsl:value-of select='property:getString("org.mathdox.phrasebook.geogebra.archive.version4")'/>
                        </xsl:when>
                        <xsl:otherwise>
                          <xsl:value-of select='property:getString("org.mathdox.phrasebook.geogebra.archive")'/>
                        </xsl:otherwise>
                      </xsl:choose>
                    </xsl:variable> 
    
                    <!--
                      if the filename starts with '/' a codebase '/' will be added
                      later. If the archive starts with a '/', remove it so that 
                      the codebase can be used.
                    -->
                    <xsl:attribute name='archive'>
                      <xsl:choose>
                        <xsl:when test='starts-with($imagedata/@fileref, "/") and 
                          starts-with($archive,"/")'
                        >
                          <xsl:value-of select='substring($archive,2)'/>
                        </xsl:when>
                        <xsl:otherwise>
                          <xsl:value-of select='$archive'/>
                        </xsl:otherwise>
                      </xsl:choose>
                    </xsl:attribute>
                    
                    <!--
                      handle all attributes
                    -->
                    <xsl:apply-templates select='$imagedata/@*'/>
                    <!--
                      add the parameters (one of these is the filename)
                      if the filename starts with /, then move that / to the
                      codebase
                    -->
                    <xsl:if test='$imagedata/@fileref'>
                      <xsl:choose>
                        <xsl:when test='starts-with($imagedata/@fileref, "/")'>
                          <xsl:attribute name='codebase' select='"/"'/>
                          <xhtml:param name='filename' 
                            value='{substring($imagedata/@fileref,2)}'
                          />
                        </xsl:when>
                        <xsl:otherwise>
                          <xhtml:param name='filename' 
                            value='{$imagedata/@fileref}'
                          />
                        </xsl:otherwise>
                      </xsl:choose>
                    </xsl:if>
                    <xsl:if test='not($imagedata/xhtml:param[@name="framePossible"])'>
                      <xhtml:param name='framePossible' value='false'/>
                    </xsl:if>
                    <xsl:apply-templates select='$imagedata/xhtml:param'/>
                  </xhtml:applet>
                </xsl:otherwise>
              </xsl:choose>
            </xsl:template>
    
            <!--
              rename depth to height
            -->
            <xsl:template match='imagedata[@format="geogebra"]/@depth'>
              <xsl:attribute name='height' select='.'/>
            </xsl:template>
    
            <!--
              remove fileref and format, which are already used
            -->
            <xsl:template match='imagedata[@format="geogebra"]/@fileref'/>
            <xsl:template match='imagedata[@format="geogebra"]/@format'/>
            <xsl:template match='imagedata[@format="geogebra"]/@version'/>
    
            <!--
              remove parameters for code and archive which can not be changed this way
              NOTE: archive can be changed by editing configuration/properties.xml
            -->
            <xsl:template match='imagedata[@format="geogebra"]/xhtml:param[@name="archive"]'/>
            <xsl:template match='imagedata[@format="geogebra"]/xhtml:param[@name="code"]'/>

            <xsl:template match='imagedata[@format="geogebra"]/@*' mode='geogebraweb'/>

            <xsl:template match='*' mode='geogebraweb'>
              <xsl:apply-templates mode='#current'/>
            </xsl:template>

            <xsl:template match='imagedata[@format="geogebra"]/@depth' mode='geogebraweb' priority="2">
              <xsl:attribute name='data-param-height' select='.'/>
            </xsl:template>

            <xsl:template match='imagedata[@format="geogebra"]/@fileref' mode='geogebraweb' priority="2">
              <xsl:attribute name='data-param-filename' select='.'/>
            </xsl:template>

            <xsl:template match='imagedata[@format="geogebra"]/@height' mode='geogebraweb' priority="2">
              <xsl:attribute name='data-param-height' select='.'/>
            </xsl:template>

            <xsl:template match='imagedata[@format="geogebra"]/@name' mode='geogebraweb' priority="2">
              <xsl:attribute name='data-param-id' select='.'/>
            </xsl:template>

            <xsl:template match='imagedata[@format="geogebra"]/@width' mode='geogebraweb' priority="2">
              <xsl:attribute name='data-param-width' select='.'/>
            </xsl:template>

            <xsl:template match='xhtml:param[@name="language"]' mode='geogebraweb' priority="2">
              <xsl:attribute name='data-param-language' select='@value'/>
            </xsl:template>
          </xsl:transform>
        </p:input>
        <p:input name='data' href='#data'/>
        <p:output name='data' id='geogebra-image'/>
      </p:processor>

      <!-- search for filenames -->
      <p:processor name='oxf:xslt'>
        <p:input name='config'>
          <xsl:transform version='2.0'>
            <xsl:template match='/'>
              <filenames>
                <xsl:apply-templates/>
              </filenames>
            </xsl:template>

            <xsl:template match='xhtml:applet[@code="geogebra.GeoGebraApplet"]/xhtml:param[@name="filename"] | mathdox:geogebrafile'>
              <filename>
                <xsl:attribute name='href'>
                  <xsl:if test='not(starts-with("/",@value))'>
                    <xsl:if test='..[@codebase="/"] and not(self::mathdox:geogebrafile)'>
                      <xsl:text>/</xsl:text>
                    </xsl:if>
                  </xsl:if>
                  <xsl:value-of select='@value'/>
                </xsl:attribute>
              </filename>
            </xsl:template>

            <xsl:template match='xhtml:article/@data-param-filename'>
              <filename>
                <xsl:attribute name='href' select='.'/>
              </filename>
            </xsl:template>

            <xsl:template match='*'>
              <xsl:apply-templates select='@*'/>
              <xsl:apply-templates/>
            </xsl:template>

            <xsl:template match='@*'/>

            <xsl:template match='text()'/>
          </xsl:transform>
        </p:input>
        <p:input name='data' href='#geogebra-image'/>
        <p:output name='data' id='geogebra-filenames'/>
      </p:processor>

      <!-- search for filenames -->
      <p:processor name='oxf:xslt'>
        <p:input name='config'>
          <xsl:transform version='2.0'>
            <xsl:template match='/*'>
              <filenames>
                <xsl:for-each-group select='filename' group-by='@href'>
                  <filename href='{current-grouping-key()}'/>
                </xsl:for-each-group>
              </filenames>
            </xsl:template>
          </xsl:transform>
        </p:input>
        <p:input name='data' href='#geogebra-filenames'/>
        <p:output name='data' id='geogebra-filenames-sorted'/>
      </p:processor>

      <p:for-each href='#geogebra-filenames-sorted' select='/filenames/filename' 
        root='ggbfiles' id='geogebra-file'
      >
        <!-- create instance -->
        <p:processor name='oxf:xslt'>
          <p:input name='config'>
            <instance xsl:version='2.0'>
              <xsl:variable name='instance' select='document("input:instance")/*'/>

              <resource>
                <xsl:choose>
                  <xsl:when test='starts-with(/*/@href, "/")'>
                    <xsl:value-of select='/*/@href'/>
                  </xsl:when>
                  <xsl:otherwise>
                    <xsl:value-of select='string-join(subsequence(tokenize($instance/resource, "/"), 1, count(tokenize($instance/resource, "/"))-1), "/")'/>
                    <xsl:text>/</xsl:text>
                    <xsl:value-of select='/*/@href'/>
                  </xsl:otherwise>
                </xsl:choose>
              </resource>

              <temporary>
                <xsl:copy-of select='$instance/temporary'/>
              </temporary>
            </instance>
          </p:input>
          <p:input name='data' href='current()'/>
          <p:input name='instance' href='#instance'/>
          <p:output name='data' id='geogebra-filename-instance'/>
        </p:processor>
        <!-- load file -->

        <p:processor name='oxf:pipeline'>
          <p:input name='config' href='oxf:/storage/load-resource.xpl'/>
          <p:input name='instance' href='#geogebra-filename-instance'/>
          <p:output name='data' id='geogebra-file-contents'/>
        </p:processor>
        
        <p:processor name='oxf:identity'>
          <p:input name='data' href='current()'/>
          <p:output name='data' id='current'/>
        </p:processor>

        <p:processor name='oxf:identity'>
          <p:input name='data' href="aggregate('wrapper', #current, #geogebra-file-contents)"/>
          <p:output name='data' ref='geogebra-file'/>
        </p:processor>

      </p:for-each>

      <p:processor name='oxf:xslt'>
        <p:input name='config'>
          <xsl:transform version='2.0'>
            <xsl:import href='oxf:/oxf/xslt/utils/copy.xsl'/>

            <xsl:variable name='geogebra-file' select='document("input:geogebra-file")/*'/>

            <xsl:template match='xhtml:applet[@code="geogebra.GeoGebraApplet"]/xhtml:param[@name="filename"] | mathdox:geogebrafile'>
              <xsl:variable name='filename'>
                <xsl:if test='not(starts-with("/",@value))'>
                  <xsl:if test='..[@codebase="/"] and not(self::mathdox:geogebrafile)'>
                    <xsl:text>/</xsl:text>
                  </xsl:if>
                </xsl:if>
                <xsl:value-of select='@value'/>
              </xsl:variable>

              <xsl:choose>
                <xsl:when test='$geogebra-file/*/filename[@href=$filename]'>
                  <xsl:choose>
                    <xsl:when test='self::mathdox:geogebrafile'>
                      <xhtml:script type='text/javascript'>
                        <xsl:text>var mathdox_geogebrafile64 = '</xsl:text>
                        <!-- does not check for filename ?! -->
                        <xsl:value-of select='string-join(tokenize($geogebra-file/*[filename/@href=$filename]/document,"\s+"), "")'/>
                        <xsl:text>';</xsl:text>
                      </xhtml:script>
                    </xsl:when>
                    <xsl:otherwise>
                      <xhtml:param name='ggbBase64'>
                        <xsl:attribute name='value'>
                          <!-- does not check for filename ?! -->
                          <xsl:value-of select='string-join(tokenize($geogebra-file/*[filename/@href=$filename]/document,"\s+"), "")'/>
                        </xsl:attribute>
                      </xhtml:param>
                    </xsl:otherwise>
                  </xsl:choose>
                </xsl:when>
                <xsl:otherwise>
                  <xsl:copy-of select='.'/>
                </xsl:otherwise>
              </xsl:choose>
            </xsl:template>

            <xsl:template match='xhtml:article/@data-param-filename'>
              <xsl:variable name='filename'>
                <xsl:value-of select='.'/>
              </xsl:variable>

              <xsl:attribute name='data-param-ggbbase64'>
                <xsl:value-of select='string-join(tokenize($geogebra-file/*[filename/@href=$filename]/document,"\s+"), "")'/>
              </xsl:attribute>
            </xsl:template>

          </xsl:transform>
        </p:input>
        <p:input name='data' href='#geogebra-image'/>
        <p:input name='geogebra-file' href='#geogebra-file'/>
        <p:output name='data' id='geogebra-with-base64'/>
      </p:processor>

      <!--
        Convert applet codebases
        It is probably faster to add applet/codebase to the rewriter processors
      -->
      <p:processor name='oxf:unsafe-xslt'>
        <p:input name='config'>
          <xsl:transform version='2.0'>
            <xsl:import href='oxf:/oxf/xslt/utils/copy.xsl'/>
    
            <!--
              rewrite an applet in a mediaobject if it is the first element: put it
              around the mediaobject (and let the mediaobject be the alternative)
            -->
            <xsl:template match='mediaobject | inlinemediaobject |
              mediaobjectco | inlinemediaobjectco'
            >
              <xsl:choose>
                <xsl:when test='xhtml:applet[not(preceding-sibling::*)]'>
                  <!--
                    first the applet tag and its attributes/parameters
                  -->
                  <xhtml:applet>
                    <xsl:apply-templates select='*[1]/@*'/>
                    <xsl:apply-templates select='*[1]/*'/>
                    <!--
                      Then the alternatives (if there are any)
                    -->
                    <xsl:if test='*[position() &gt; 1]'>
                      <xsl:copy>
                        <xsl:apply-templates select='@*'/>
                        <xsl:apply-templates select='*[ position() &gt; 1 ]'/>
                      </xsl:copy>
                    </xsl:if>
                  </xhtml:applet>
                </xsl:when>
                <xsl:otherwise>
                  <xsl:copy>
                    <xsl:apply-templates select='@*'/>
                    <xsl:apply-templates select='*'/>
                  </xsl:copy>
                </xsl:otherwise>
              </xsl:choose>
            </xsl:template>
    
            <xsl:template match='xhtml:applet[@code="geogebra.GeoGebraApplet"]/xhtml:param[@name="filename"]'>
              <xsl:copy>
                <xsl:apply-templates select='@*[name()!="value"]'/>
                <xsl:attribute name='value'>
                  <xsl:value-of select='context:rewriteResourceURL(@value)'/>
                </xsl:attribute>
              </xsl:copy>
            </xsl:template>
          </xsl:transform>
        </p:input>
        <p:input name='data' href='#geogebra-with-base64'/>
        <p:output name='data' ref='data'/>
      </p:processor>
    </p:otherwise>
  </p:choose>
</p:config>