<!--
  Handles serialization to the browser.
  2006-01-31
  Rikko Verrijzer, Mark Spanbroek
-->
<p:config 
  xmlns:context='java:org.orbeon.oxf.pipeline.StaticExternalContext'
  xmlns:mathml='http://www.w3.org/1998/Math/MathML'
  xmlns:oxf='http://www.orbeon.com/oxf/processors'
  xmlns:p='http://www.orbeon.com/oxf/pipeline'
  xmlns:property='java:org.mathdox.player.PropertyWrapper'
  xmlns:saxon='http://saxon.sf.net/'
  xmlns:xforms='http://www.w3.org/2002/xforms'
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:xsl='http://www.w3.org/1999/XSL/Transform'
  xmlns:xhtml='http://www.w3.org/1999/xhtml'
>

  <p:param type='input' name='data'/>
  <p:param type='input' name='instance'/>
  <p:param type='input' name='xforms-model'/>

  <!--
    Test whether the result is html.
  -->
  <p:choose href='#data'>
    <p:when test='/xhtml:html'>
     
      <!--
        Check whether to translate mathml to tex and to add the jsMath renderer
        TODO: possibly check for spans with role math and if so add jsMath
        anyway
      -->
      <p:choose href='#instance'>
        <p:when test='p:property("org.mathdox.mathematics.display") = "mathml"'>
          <p:processor name='oxf:identity'>
            <p:input name='data' href='#data'/>
            <p:output name='data' id='data-after-math'/>
          </p:processor>
        </p:when>
        <!-- mathjax latex -->
        <p:when test='p:property("org.mathdox.mathematics.display") = "mathjax"'>
        <!--
          default: transform mathml to tex and add the MathJax script
        -->
          <!--
            If the result is html, convert mathml to tex, and add MathJax renderer.
          -->
          <p:processor name='oxf:unsafe-xslt'>
            <p:input name='config'>
              <xsl:transform version='2.0'>
                <xsl:import href='oxf:/oxf/xslt/utils/copy.xsl'/>
                <xsl:import href='oxf:/util/xsltml/mmltex.xsl'/>

                <xsl:template match='mathml:*[not(parent::mathml:*)]'>
                  <xsl:param name='math' select='false()' tunnel='yes' as='xs:boolean'/>

                  <xsl:choose>
                    <xsl:when test='not($math)'>
                      <xhtml:script type='math/tex'>
                        <xsl:choose>
                          <xsl:when test='self::mathml:math'>
                            <xsl:apply-templates>
			      <xsl:with-param name='math' select='true()' tunnel='yes' as='xs:boolean'/>
			    </xsl:apply-templates>
                          </xsl:when>
                          <xsl:otherwise>
                            <xsl:apply-imports/>
                          </xsl:otherwise>
                        </xsl:choose>
                      </xhtml:script>
                    </xsl:when>
                    <xsl:otherwise>
                      <!-- already inside math; do not add another script header -->
                      <xsl:choose>
                        <xsl:when test='self::mathml:math'>
                          <xsl:apply-templates>
			    <xsl:with-param name='math' select='true()' tunnel='yes' as='xs:boolean'/>
			  </xsl:apply-templates>
                        </xsl:when>
                        <xsl:otherwise>
                          <xsl:apply-imports/>
                        </xsl:otherwise>
                      </xsl:choose>
                    </xsl:otherwise>
                  </xsl:choose> 
                </xsl:template>

                <xsl:template match='xhtml:head'>
                  <xsl:copy>
                    <xsl:for-each select='@*'>
                      <xsl:copy/>
                    </xsl:for-each>
                    <xsl:apply-templates/>
                    <xhtml:script
                      type='text/javascript'
                    >
                      <xsl:attribute name='src'>
                        <xsl:value-of 
                          select='property:getString(
                            "org.mathdox.mathematics.display.mathjax.prefix")
                          '
                        />
                        <xsl:text>/MathJax.js?config=TeX-AMS_HTML</xsl:text>
                      </xsl:attribute>
                      <!--quite a few browsers cant handle <script/> tags. make sure -->
                      <!--this tag has a body to prevent these kind of browser bugs -->
                      <!--This problem mainly occurs in portlets -->
                      <!--a single ; is a body without any instruction, so thats ok-->
                      ;
                    </xhtml:script>
                  </xsl:copy>
                </xsl:template>

                <!-- convert existing jsMath expressions to MathJax -->
                <xsl:template match='xhtml:div[@class="math"]'>
                  <xhtml:script type='math/tex; mode=display'>
                    <xsl:apply-templates>
		      <xsl:with-param name='math' select='true()' as='xs:boolean' tunnel='yes'/>
		    </xsl:apply-templates>
                  </xhtml:script>
                </xsl:template>

                <xsl:template match='xhtml:span[@class="math"]'>
                  <xsl:param name='math' select='false()' tunnel='yes' as='xs:boolean'/>
		  
		  <xsl:choose>
		    <xsl:when test='$math'>
                      <xsl:apply-templates>
		        <xsl:with-param name='math' select='true()' as='xs:boolean' tunnel='yes'/>
		      </xsl:apply-templates>
		    </xsl:when>
		    <xsl:otherwise>
                      <xhtml:script type='math/tex'>
                        <xsl:apply-templates>
		          <xsl:with-param name='math' select='true()' as='xs:boolean' tunnel='yes'/>
		        </xsl:apply-templates>
                      </xhtml:script>
		    </xsl:otherwise>
		  </xsl:choose>
                </xsl:template>
              </xsl:transform>
            </p:input>
            <p:input name='data' href='#data'/>
            <p:output name='data' id='data-after-math'/>
          </p:processor>
        </p:when>
        <!-- mathjax using phrasebook service -->
        <p:when test='p:property("org.mathdox.mathematics.display") = "mathjax-phrasebook"'>
          <p:processor name="oxf:request">
            <p:input name="config">
              <config>
                <include>/request/server-port</include>
                <include>/request/is-secure</include>
              </config>
            </p:input>
            <p:output name="data" id="request"/>
          </p:processor>
    
          <p:processor name='oxf:unsafe-xslt'>
            <p:input name='config'>
              <xsl:stylesheet version='2.0'>
                <xsl:template match='/*'> 
                  <xsl:variable name='serviceurl' select='"/phrasebook/xsltml-inside-xhtml/translate_openmath_native"'/>
                  <xforms:submission method="post">
                    <xsl:attribute name='action'>
                      <xsl:text>http://localhost:</xsl:text>
                      <xsl:choose>
                        <xsl:when test='doc("input:request")/request/is-secure = "true"'>
                          <!-- use standard port instead of https, since it is internal anyway -->
                          <xsl:text>80</xsl:text>
                        </xsl:when>
                        <xsl:otherwise>
                          <xsl:value-of select='doc("input:request")/request/server-port'/>
                        </xsl:otherwise>
                      </xsl:choose>
                      <xsl:value-of select='context:rewriteResourceURL($serviceurl)'/>
                    </xsl:attribute>
                  </xforms:submission>
                </xsl:template>
              </xsl:stylesheet>
            </p:input>
            <p:input name='data' href='#instance'/>
            <p:input name='request' href='#request'/>
            <p:output name='data' id='submission'/>
          </p:processor>
    
          <!-- TODO translate url; XXX contains URL -->
          <p:processor name="oxf:xforms-submission">
            <p:input name="submission" href='#submission'/>
            <p:input name="request" href="#data"/>
            <p:output name="response" id="response"/>
          </p:processor>
    
          <p:processor name='oxf:xslt'>
            <p:input name='config'>
              <xsl:stylesheet version='2.0'>
                <xsl:template match='/*'>
                    <xsl:if test='data'>
                      <xsl:copy-of select='saxon:parse(string(data))/*'/>
                    </xsl:if>
                </xsl:template>
              </xsl:stylesheet>
            </p:input>
            <p:input name='data' href='#response'/>
            <p:output name='data' id='data-after-math'/>
          </p:processor>
	</p:when>
        <!-- mathjax mathml -->
        <p:when test='p:property("org.mathdox.mathematics.display") = "mathjax-mathml"'>
        <!--
          default: transform mathml to jsmath and add the jsmath script
        -->
          <!--
            If the result is html, convert mathml to tex, and add jsMath renderer.
          -->
          <p:processor name='oxf:unsafe-xslt'>
            <p:input name='config'>
              <xsl:transform version='2.0'>
                <xsl:import href='oxf:/oxf/xslt/utils/copy.xsl'/>
               
                <!-- strip mathml namespace -->
                <xsl:template match='mathml:*'>
                  <xsl:element name='{local-name()}'>
                    <xsl:copy-of select='@*'/>
                    <xsl:apply-templates/>
                  </xsl:element>
                </xsl:template>

                <xsl:template match='xhtml:head'>
                  <xsl:copy>
                    <xsl:for-each select='@*'>
                      <xsl:copy/>
                    </xsl:for-each>
                    <xsl:apply-templates/>
                    <xhtml:script type="text/x-mathjax-config">
                      MathJax.Hub.Config({
                          extensions: ["jsMath2jax.js"]
                      });
                    </xhtml:script>
                    <xhtml:script
                      type='text/javascript'
                    >
                      <xsl:attribute name='src'>
                        <xsl:value-of 
                          select='property:getString(
                            "org.mathdox.mathematics.display.mathjax.prefix")
                          '
                        />
                        <xsl:text>/MathJax.js?config=TeX-AMS-MML_HTMLorMML</xsl:text>
                      </xsl:attribute>
                      <!--quite a few browsers cant handle <script/> tags. make sure -->
                      <!--this tag has a body to prevent these kind of browser bugs -->
                      <!--This problem mainly occurs in portlets -->
                      <!--a single ; is a body without any instruction, so thats ok-->
                      ;
                    </xhtml:script>
                  </xsl:copy>
                </xsl:template>
              </xsl:transform>
            </p:input>
            <p:input name='data' href='#data'/>
            <p:output name='data' id='data-after-math'/>
          </p:processor>
        </p:when>
        <p:otherwise>
          <!--
            If the result is html, convert mathml to tex, and add jsMath renderer.
          -->
          <p:processor name='oxf:unsafe-xslt'>
            <p:input name='config'>
              <xsl:transform version='2.0'>
                <xsl:import href='oxf:/oxf/xslt/utils/copy.xsl'/>
                <xsl:import href='oxf:/util/xsltml/mmltex.xsl'/>
                <xsl:template match='mathml:*[not(parent::mathml:*)]'>
                  <xhtml:span class='math'>
                    <xsl:choose>
                      <xsl:when test='self::mathml:math'>
                        <xsl:apply-templates/>
                      </xsl:when>
                      <xsl:otherwise>
                        <xsl:apply-imports/>
                      </xsl:otherwise>
                    </xsl:choose>
                  </xhtml:span>
                </xsl:template>
                <xsl:template match='xhtml:head'>
                  <xsl:copy>
                    <xsl:for-each select='@*'>
                      <xsl:copy/>
                    </xsl:for-each>
                    <xsl:apply-templates/>
                    <xhtml:script type='text/javascript'>
                      jsMath = {styles: {'#jsMath_button': 'display:none;'}};
                    </xhtml:script>
                    <xhtml:script
                      type='text/javascript'
                    >
                      <xsl:attribute name='src'>
                        <xsl:value-of 
                          select='property:getString(
                            "org.mathdox.mathematics.display.jsmath.prefix")
                          '
                        />
                        <xsl:text>/jsMath.js</xsl:text>
                      </xsl:attribute>
                      <!--quite a few browsers cant handle <script/> tags. make sure -->
                      <!--this tag has a body to prevent these kind of browser bugs -->
                      <!--This problem mainly occurs in portlets -->
                      <!--a single ; is a body without any instruction, so thats ok-->
                      ;
                    </xhtml:script>
                    <xhtml:script type='text/javascript'>
                      <xsl:text>jsMath.Extension.Require('AMSsymbols');</xsl:text>
                      <xsl:text>jsMath.Extension.Require('AMSmath');</xsl:text>
                    </xhtml:script>
                  </xsl:copy>
                </xsl:template>
                <xsl:template match='xhtml:body'>
                  <xsl:copy>
                    <xsl:for-each select='@*'>
                      <xsl:copy/>
                    </xsl:for-each>
                    <xsl:apply-templates/>
                    <xhtml:script type='text/javascript'>
                      jsMath.Process()
                    </xhtml:script>
                  </xsl:copy>
                </xsl:template>
              </xsl:transform>
            </p:input>
            <p:input name='data' href='#data'/>
            <p:output name='data' id='data-after-math'/>
          </p:processor>
        </p:otherwise>
      </p:choose>
      <!--
        If the result is html, add the base to the html header
      -->

      <!--
        Add base: get the request-url from the request
      -->
      <p:processor name='oxf:request'>
        <p:input name='config'>
          <config>                                      <!-- example value -->
            <include>/request/scheme</include>              <!-- http -->
            <include>/request/server-name</include>   <!-- localhost -->
            <include>/request/server-port</include>   <!-- 8080 -->
            <include>/request/context-path</include>  <!-- /mathdoxplayer -->
            <include>/request/request-path</include>     <!-- /mathadore/... -->
          </config>
        </p:input>
        <p:output name='data' id="request"/>
      </p:processor>
      
      <!--
        Add base: add the base-uri to the header
      -->
      <p:processor name='oxf:xslt'>
        <p:input name='config'>
          <xsl:transform version='2.0'>
            <xsl:import href='oxf:/oxf/xslt/utils/copy.xsl'/>

            <xsl:variable name='request' select='doc("input:request")/*'/>

            <xsl:template match='xhtml:head'>
              <xsl:copy>
                <xsl:apply-templates select="@*"/>
                <xsl:if test='not(base)'>
                  <xhtml:base>
                    <xsl:attribute name='href'>
                      <xsl:value-of select='$request/scheme'/>
                      <xsl:text>://</xsl:text>
                      <xsl:value-of select='$request/server-name'/>
                      <xsl:if test='not($request/port = "80")'>
                        <xsl:text>:</xsl:text>
                        <xsl:value-of select='$request/server-port'/>
                      </xsl:if>
                      <xsl:value-of select='replace(replace(encode-for-uri($request/context-path),"%2F","/","i"),"%3A",":","i")'/>
                      <xsl:value-of select='replace(replace(encode-for-uri($request/request-path),"%2F","/","i"),"%3A",":","i")'/>
                    </xsl:attribute>
                  </xhtml:base>
                </xsl:if>
                <xsl:apply-templates/>
              </xsl:copy>
            </xsl:template>
          </xsl:transform>
        </p:input>
        <p:input name='data' href='#data-after-math'/>
        <p:input name='request' href='#request'/>
        <p:output name='data' id='newdata'/>
      </p:processor>

    </p:when>
    <p:otherwise>

      <!-- Simply pass through the data. -->
      <p:processor name='oxf:identity'>
        <p:input name='data' href='#data'/>
        <p:output name='data' id='newdata'/>
      </p:processor>

    </p:otherwise>
  </p:choose>

  <!--
    Call the standard orbeon epilogue.
  -->
  <p:processor name='oxf:pipeline'>
    <p:input name='config' href='@parent@'/>
    <p:input name='data' href='#newdata'/>
    <p:input name='instance' href='#instance'/>
    <p:input name='xforms-model' href='#xforms-model'/>
  </p:processor>

  <p:processor name='oxf:null-serializer'>
    <p:input name='data' href='#instance'/>
  </p:processor>

</p:config>